plugins {
	id 'net.fabricmc.fabric-loom' version '1.16-SNAPSHOT'
	id 'com.diffplug.spotless' version '6.19.0'
	id "com.modrinth.minotaur" version "2.+"
}

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(25)
	}
}

repositories {
	exclusiveContent {
		forRepository {
			maven {
				name = 'Modrinth'
				url = 'https://api.modrinth.com/maven'
			}
		}
		filter {
			includeGroup 'maven.modrinth'
		}
	}
	maven { url 'https://maven.terraformersmc.com/releases/' }
	maven { url 'https://jitpack.io' }
	flatDir {
		dirs '.'
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	implementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"
	// Official 26.1 template uses `implementation` for fabric-api (not modImplementation).
	implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
	implementation "maven.modrinth:malilib:${project.malilib_version}"
	compileOnly "com.terraformersmc:modmenu:${project.mod_menu_version}"
}

group = project.group + "." + project.mod_id
base {
	archivesName = project.mod_file_name + '-' + project.minecraft_version_out
}
version = project.mod_version

if (version.endsWith('-dev')) {
	version += "." + new Date().format('yyyyMMdd.HHmmss')
}

processResources {
	inputs.property "mod_version", project.mod_version

	filesMatching("fabric.mod.json") {
		expand([
				"mod_version"          : project.version,
				"minecraft_version_min": project.property("minecraft_version_min"),
				"malilib_version"   : project.property("malilib_version")
		])
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
}

spotless {
	java {
		importOrder()
		removeUnusedImports()
		cleanthat()
		eclipse()
		formatAnnotations()
	}
}

modrinth {
	token = System.getenv("MODRINTH_TOKEN")
	syncBodyFrom = rootProject.file("README.md").text
	projectId = 'C1naQCmt'
	// Loom 1.16+ with net.fabricmc.fabric-loom (unobfuscated MC) does not create remapJar; ship the standard jar
	uploadFile = tasks.jar
	gameVersions = ['26.1.2']
	loaders = ['fabric']
	dependencies = []
}